@echo off
setlocal

set VisualStudioVersion=%~1
set Verbosity=%~2
if "%VisualStudioVersion%"=="" (
	set VisualStudioVersion=15.0
)
if "%Verbosity%"=="" (
	set Verbosity=normal
)

set _MyDir=%~dp0
set _MyDir=%_MyDir:~0,-1%

if "%VisualStudioVersion%"=="-?" goto :DisplayHelp
if "%VisualStudioVersion%"=="-h" goto :DisplayHelp
if "%VisualStudioVersion%"=="--help" goto :DisplayHelp

call FindMSBuild.bat
if not defined MSBuild goto :EOF

set VcpkgEnabled=false

"%MSBuild%" /nologo /property:VisualStudioVersion=%VisualStudioVersion% /verbosity:%Verbosity% /target:DisplayMessages "%_MyDir%\SDKs.proj"
if errorlevel 1 goto :EOF

"%MSBuild%" /nologo /property:VisualStudioVersion=%VisualStudioVersion% /verbosity:%Verbosity% /target:BuildAll "%_MyDir%\SDKs.proj"
if errorlevel 1 goto :EOF

endlocal
goto :EOF

:DisplayHelp
echo %0 ${VisualStudioVersion} ${Verbosity}
echo.
echo Where
echo   * VisualStudioVersion is 14.0 for Visual Studio 14 2015
echo   or 15.0 for Visual Studio 15 2017.
echo   * Verbosity is q[uiet], m[inimal], n[ormal], d[etailed],
echo   or diag[nostic].
echo.
echo If not specified, the following defaults are used.
echo * VisualStudioVersion: 15.0
echo * Verbosity: normal